Program f08hefe

!     F08HEF Example Program Text

!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use nag_library, Only: dsbtrd, dsteqr, nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, j, kd, ldab, ldq, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ab(:,:), d(:), e(:), q(:,:), work(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F08HEF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, kd
      ldab = kd + 1
      ldq = n
      Allocate (ab(ldab,n),d(n),e(n-1),q(ldq,n),work(2*n-2))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Do i = 1, n
          Read (nin,*)(ab(kd+1+i-j,j),j=i,min(n,i+kd))
        End Do
      Else If (uplo=='L') Then
        Do i = 1, n
          Read (nin,*)(ab(1+i-j,j),j=max(1,i-kd),i)
        End Do
      End If

!     Reduce A to tridiagonal form T = (Q**T)*A*Q (and form Q)
!     The NAG name equivalent of dsbtrd is f08hef
      Call dsbtrd('V',uplo,n,kd,ab,ldab,d,e,q,ldq,work,info)

!     Calculate all the eigenvalues and eigenvectors of A
!     The NAG name equivalent of dsteqr is f08jef
      Call dsteqr('V',n,d,e,q,ldq,work,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) d(1:n)
        Write (nout,*)
        Flush (nout)

!       Standardize the eigenvectors so that first elements are non-negative.
        Do i = 1, n
          If (q(1,i)<0.0_nag_wp) Then
            q(1:n,i) = -q(1:n,i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf('General',' ',n,n,q,ldq,'Eigenvectors',ifail)

      End If

99999 Format (3X,(8F8.4))
    End Program f08hefe