Program f07uufe

!     F07UUF Example Program Text

!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, ztpcon
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: diag = 'N', norm = '1'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: rcond
      Integer                          :: i, info, j, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ap(:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07UUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (ap(n*(n+1)/2),work(2*n),rwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

!     Estimate condition number
!     The NAG name equivalent of ztpcon is f07uuf
      Call ztpcon(norm,uplo,diag,n,ap,rcond,work,rwork,info)

      Write (nout,*)
      If (rcond>=x02ajf()) Then
        Write (nout,99999) 'Estimate of condition number =',                   &
          1.0E0_nag_wp/rcond
      Else
        Write (nout,*) 'A is singular to working precision'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07uufe