Program f07fd_a1w_fe

!     F07FD_A1W_F Example Program Text
!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07fd_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, info, lda, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Type (nagad_a1w_w_rtype), Allocatable :: a(:,:), ax(:,:)
      Real (Kind=nag_wp), Allocatable  :: ar(:,:), ddda(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FD_A1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),ax(lda,n))
      Allocate (ar(lda,n),ddda(n,n))

!     Read A from data file

      ar = 0.0_nag_wp
      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(ar(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(ar(i,1:i),i=1,n)
      End If
      a = ar

!     Create AD tape
      Call nagad_a1w_ir_create

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Call nagad_a1w_ir_register_variable(a)

      ax = a
!     Factorize A
!     The NAG name equivalent of dpotrf_a1w is f07fd_a1w_f
      Call f07fd_a1w_f(ad_handle,uplo,n,ax,lda,info)

      Write (nout,*)
      Flush (nout)
      If (info==0) Then

!       Print factor
        ar(1:n,1:n) = ax(1:n,1:n)%value
!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf(uplo,'Nonunit',n,n,ar,lda,'Factor',ifail)

      Else
        Write (nout,*) 'A is not positive definite'
        Go To 100
      End If
      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order adjoints'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of diagonal of L w.r.t. first column of A:'
!     Setup evaluation of derivatives via adjoints
      Do i = 1, n
        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(ax(i,i),1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        ddda(i,1:n) = nagad_a1w_get_derivative(a(1:n,1))
      End Do
      Call x04caf('General',' ',n,n,ddda,n,'',ifail)

!     Remove computational data object and tape
100   Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove


    End Program f07fd_a1w_fe