Program f07btfe

!     F07BTF Example Program Text

!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use nag_library, Only: f06kcf, nag_wp, x02ajf, x02amf, x02bhf, x04def,   &
                             zdscal, zgbequ
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: one = 1.0_nag_wp
      Real (Kind=nag_wp), Parameter    :: thresh = 0.1_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: amax, big, colcnd, rowcnd, small
      Integer                          :: i, i0, i1, ifail, ilen, info, j, k,  &
                                          kl, ku, ldab, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ab(:,:)
      Real (Kind=nag_wp), Allocatable  :: c(:), r(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min, real
!     .. Executable Statements ..
      Write (nout,*) 'F07BTF Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, kl, ku
      ldab = kl + ku + 1
      Allocate (ab(ldab,n),c(n),r(n))

!     Read the band matrix A from data file

      k = ku + 1
      Read (nin,*)((ab(k+i-j,j),j=max(i-kl,1),min(i+ku,n)),i=1,n)

!     Print the matrix A

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04def(n,n,kl,ku,ab,ldab,'Matrix A',ifail)

      Write (nout,*)

!     Compute row and column scaling factors

!     The NAG name equivalent of zgbequ is f07btf
      Call zgbequ(n,n,kl,ku,ab,ldab,r,c,rowcnd,colcnd,amax,info)

      If (info>0) Then
        If (info<=n) Then
          Write (nout,99999) 'Row ', info, ' of A is exactly zero'
        Else
          Write (nout,99999) 'Column ', info - n, ' of A is exactly zero'
        End If
      Else

!       Print ROWCND, COLCND, AMAX and the scale factors

        Write (nout,99998) 'ROWCND =', rowcnd, ', COLCND =', colcnd,           &
          ', AMAX =', amax
        Write (nout,*)
        Write (nout,*) 'Row scale factors'
        Write (nout,99997) r(1:n)
        Write (nout,*)
        Write (nout,*) 'Column scale factors'
        Write (nout,99997) c(1:n)
        Write (nout,*)
        Flush (nout)

!       Compute values close to underflow and overflow

        small = x02amf()/(x02ajf()*real(x02bhf(),kind=nag_wp))
        big = one/small
        If ((rowcnd>=thresh) .And. (amax>=small) .And. (amax<=big)) Then
          If (colcnd<thresh) Then

!           Just column scale A
!           The NAG name equivalent of zdscal is f06jdf
            Do j = 1, n
              i1 = 1 + max(1,j-ku) - (j-ku)
              ilen = min(n,j+kl) - max(1,j-ku) + 1
              Call zdscal(ilen,c(j),ab(i1,j),1)
            End Do

          End If
        Else If (colcnd>=thresh) Then

!         Just row scale A
          Do j = 1, n
            i0 = max(1,j-ku)
            i1 = 1 + i0 - (j-ku)
            ilen = min(n,j+kl) - i0 + 1
            Call f06kcf(ilen,r(i0),1,ab(i1,j),1)
          End Do

        Else

!         Row and column scale A
          Do j = 1, n
            i0 = max(1,j-ku)
            i1 = 1 + i0 - (j-ku)
            ilen = min(n,j+kl) - i0 + 1
            Call zdscal(ilen,c(j),ab(i1,j),1)
            Call f06kcf(ilen,r(i0),1,ab(i1,j),1)
          End Do

        End If

!       Print the scaled matrix
        ifail = 0
        Call x04def(n,n,kl,ku,ab,ldab,'Scaled matrix',ifail)

      End If

99999 Format (1X,A,I4,A)
99998 Format (1X,3(A,1P,E8.1))
99997 Format ((1X,1P,7E11.2))
    End Program f07btfe