!   D01RK_T1W_F Example Program Text
!   Mark 27.3 Release. NAG Copyright 2021.

    Module d01rk_t1w_fe_mod

!     .. Use Statements ..
      Use nagad_library, Only: cos, nagad_t1w_w_rtype, sin, Operator (*)
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: f
!     .. Parameters ..
      Integer, Parameter, Public       :: nout = 6
    Contains
      Subroutine f(ad_handle,x,nx,fv,iflag,iuser,ruser,cpuser)
!       .. Use Statements ..
        Use, Intrinsic                 :: iso_c_binding, Only: c_ptr
!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Type (c_ptr), Intent (In)      :: cpuser
        Integer, Intent (Inout)        :: iflag
        Integer, Intent (In)           :: nx
!       .. Array Arguments ..
        Type (nagad_t1w_w_rtype), Intent (Out) :: fv(nx)
        Type (nagad_t1w_w_rtype), Intent (Inout) :: ruser(*)
        Type (nagad_t1w_w_rtype), Intent (In) :: x(nx)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Executable Statements ..
        fv = x*sin(ruser(1)*x)*cos(ruser(2)*x)
        Return
      End Subroutine f
    End Module d01rk_t1w_fe_mod

    Program d01rk_t1w_fe

!     D01RK_T1W_F Example Main Program

!     .. Use Statements ..
      Use d01rk_t1w_fe_mod, Only: f, nout
      Use, Intrinsic                   :: iso_c_binding, Only: c_null_ptr,     &
                                          c_ptr
      Use nagad_library, Only: d01rk_t1w_f, nagad_t1w_w_rtype, x10aa_t1w_f,    &
                               x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x01aaf
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (nagad_t1w_w_rtype)         :: a, abserr, b, epsabs, epsrel, result
      Type (c_ptr)                     :: ad_handle, cpuser
      Real (Kind=nag_wp)               :: dr1, dr2, pi
      Integer                          :: ifail, key, liinfo, lrinfo, maxsub
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: rinfo(:)
      Type (nagad_t1w_w_rtype)         :: ruser(2)
      Integer, Allocatable             :: iinfo(:)
      Integer                          :: iuser(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max
!     .. Executable Statements ..

      Write (nout,*) 'D01RK_T1W_F Example Program Results'

      key = 6
      pi = x01aaf(pi)

!     Initialize AD types
      a = 0.0_nag_wp
      b = 2.0_nag_wp*pi
      epsabs = 0.0_nag_wp
      epsrel = 1.0E-4_nag_wp

      maxsub = 20
      lrinfo = 4*maxsub
      liinfo = max(maxsub,4)

      Allocate (rinfo(lrinfo),iinfo(liinfo))

      iuser(1) = 0
      ruser(1) = 30.0_nag_wp
      ruser(2) = 1.0_nag_wp
      cpuser = c_null_ptr

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

!     Evaluate the integral using the AD routine
      ruser(1)%tangent = 1.0_nag_wp
      ifail = -1
      Call d01rk_t1w_f(ad_handle,f,a,b,key,epsabs,epsrel,maxsub,result,abserr, &
        rinfo,iinfo,iuser,ruser,cpuser,ifail)
      ruser(1)%tangent = 0.0_nag_wp

      If (ifail<0) Then
        Write (nout,99999) 'The routine has failed with ifail = ', ifail
        Go To 100
99999   Format (1X,A,I0)
      End If
!     Print inputs and primal outputs
      Write (nout,*)
      Write (nout,99998) 'a     ', 'lower limit of integration', a%value
      Write (nout,99998) 'b     ', 'upper limit of integration', b%value
      Write (nout,99995) 'key   ', 'choice of Gaussian rule', key
      Write (nout,99997) 'epsabs', 'absolute accuracy requested', epsabs%value
      Write (nout,99997) 'epsrel', 'relative accuracy requested', epsrel%value
      Write (nout,99995) 'maxsub', 'max number of subintervals', maxsub
      Write (nout,*)
      If (ifail>=0) Then
        Write (nout,99996) 'result', 'approximation to the integral',          &
          result%value
        Write (nout,99997) 'abserr', 'estimate of the absolute error',         &
          abserr%value
        Write (nout,99995) 'iinfo(1)', 'number of subintervals used', iinfo(1)
      End If
99998 Format (1X,A6,' - ',A30,' = ',F10.4)
99997 Format (1X,A6,' - ',A30,' = ',E10.2)
99996 Format (1X,A6,' - ',A30,' = ',F10.5)
99995 Format (1X,A6,' - ',A30,' = ',I10)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

!     Get derivatives
      dr1 = result%tangent

      ruser(2)%tangent = 1.0_nag_wp
      ifail = -1
      Call d01rk_t1w_f(ad_handle,f,a,b,key,epsabs,epsrel,maxsub,result,abserr, &
        rinfo,iinfo,iuser,ruser,cpuser,ifail)
      ruser(2)%tangent = 0.0_nag_wp

      dr2 = result%tangent

      Write (nout,*) ' Derivatives:'
      Write (nout,99994) 'd(result)/druser(1) =', dr1
      Write (nout,99994) 'd(result)/druser(2) =', dr2
99994 Format (1X,A15,1X,F10.5)

100   Continue
!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program d01rk_t1w_fe