Program s01ba_t1w_fe

!     S01BA_T1W_F Example Program Text
!     Mark 27.1 Release. NAG Copyright 2020.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: nagad_t1w_inc_derivative, nagad_t1w_w_rtype,    &
                               s01ba_t1w_f, x10aa_t1w_f, x10ab_t1w_f,          &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_t1w_w_rtype)         :: x, y
      Real (Kind=nag_wp)               :: dydx, xr
      Integer                          :: i, ifail, n
!     .. Executable Statements ..
      Write (nout,*) 'S01BA_T1W_F Example Program Results'

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Write (nout,*)
      Write (nout,*) '       x       y=ln(1+x)     dy/dx'

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Read (nin,*) xr

        x = xr
        Call nagad_t1w_inc_derivative(x,1.0_nag_wp)

        ifail = -1
        Call s01ba_t1w_f(ad_handle,x,y,ifail)

        If (ifail<0) Then
          Write (nout,99999) x%value, 'fail = ', ifail
        Else
          dydx = y%tangent
          Write (nout,99998) x%value, y%value, dydx
        End If
      End Do
99999 Format (1X,1P,E12.4,1X,A12,I0)
99998 Format (1X,1P,3E12.4)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program s01ba_t1w_fe