Program g05tbfe

!     G05TBF Example Program Text

!     Mark 27.1 Release. NAG Copyright 2020.

!     .. Use Statements ..
      Use nag_library, Only: g05kff, g05tbf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: lseed = 1, nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: p
      Integer                          :: genid, ifail, lstate, n, subid
!     .. Local Arrays ..
      Integer                          :: seed(lseed)
      Integer, Allocatable             :: state(:)
      Logical, Allocatable             :: x(:)
!     .. Executable Statements ..
      Write (nout,*) 'G05TBF Example Program Results'
      Write (nout,*)

!     Skip heading in data file
      Read (nin,*)

!     Read in the base generator information and seed
      Read (nin,*) genid, subid, seed(1)

!     Initial call to initializer to get size of STATE array
      lstate = 0
      Allocate (state(lstate))
      ifail = 0
      Call g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!     Reallocate STATE
      Deallocate (state)
      Allocate (state(lstate))

!     Initialize the generator to a repeatable sequence
      ifail = 0
      Call g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!     Read in sample size
      Read (nin,*) n

!     Read in the distribution parameters
      Read (nin,*) p

      Allocate (x(n))

!     Generate the variates
      ifail = 0
      Call g05tbf(n,p,state,x,ifail)

!     Display the variates
      Write (nout,99999) x(1:n)

99999 Format (1X,L1)
    End Program g05tbfe