Program g01ec_t1w_fe

!     G01EC_T1W_F Example Program Text
!     Mark 27 Release. NAG Copyright 2019.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g01ec_t1w_f, nagad_t1w_inc_derivative,          &
                               nagad_t1w_w_rtype, x10aa_t1w_f, x10ab_t1w_f,    &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_t1w_w_rtype)         :: df, p, x
      Real (Kind=nag_wp)               :: dfr, dpdf, dpdx, xr
      Integer                          :: i, ifail, n
      Character (1)                    :: tail
!     .. Executable Statements ..
      Write (nout,*) 'G01EC_T1W_F Example Program Results'

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      tail = 'L'
      Write (nout,*)
      Write (nout,*) 'Left tail significance levels and derivatives'
      Write (nout,*)
      Write (nout,*) '   x            df           p            dp/dx' //      &
        '       dp/ddf'

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Read (nin,*) xr, dfr

        x = xr
        df = dfr
        Call nagad_t1w_inc_derivative(x,1.0_nag_wp)

        ifail = 0
        Call g01ec_t1w_f(ad_handle,tail,x,df,p,ifail)
        dpdx = p%tangent

        x = xr
        df = dfr
        Call nagad_t1w_inc_derivative(df,1.0_nag_wp)

        ifail = 0
        Call g01ec_t1w_f(ad_handle,tail,x,df,p,ifail)
        dpdf = p%tangent

        Write (nout,99999) x%value, p%value, df%value, dpdx, dpdf
      End Do
99999 Format (1X,1P,5E13.4)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program g01ec_t1w_fe