Program f08fufe

!     F08FUF Example Program Text

!     Mark 27.1 Release. NAG Copyright 2020.

!     .. Use Statements ..
      Use nag_library, Only: dstebz, nag_wp, x04dbf, zhetrd, zscal, zstein,    &
                             zunmtr
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0E0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: vl, vu
      Integer                          :: i, ifail, info, k, lda, ldc, lwork,  &
                                          m, n, nsplit
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), c(:,:), tau(:), work(:)
      Real (Kind=nag_wp), Allocatable  :: d(:), e(:), rwork(:), w(:)
      Integer, Allocatable             :: iblock(:), ifailv(:), isplit(:),     &
                                          iwork(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: abs, cmplx, conjg, maxloc
!     .. Executable Statements ..
      Write (nout,*) 'F08FUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      ldc = n
      lwork = 64*n
      Allocate (a(lda,n),c(ldc,n),tau(n),work(lwork),d(n),e(n),rwork(5*n),     &
        w(n),iblock(n),ifailv(n),isplit(n),iwork(3*n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Reduce A to tridiagonal form T = (Q**H)*A*Q
!     The NAG name equivalent of zhetrd is f08fsf
      Call zhetrd(uplo,n,a,lda,d,e,tau,work,lwork,info)

!     Calculate the two smallest eigenvalues of T (same as A)

!     The NAG name equivalent of dstebz is f08jjf
      Call dstebz('I','B',n,vl,vu,1,2,zero,d,e,m,nsplit,w,iblock,isplit,rwork, &
        iwork,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else
        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) w(1:m)

!       Calculate the eigenvectors of T, storing the result in C
!       The NAG name equivalent of zstein is f08jxf
        Call zstein(n,d,e,m,w,iblock,isplit,c,ldc,rwork,iwork,ifailv,info)

        If (info>0) Then
          Write (nout,*) 'Failure to converge.'
        Else

!         Calculate the eigenvectors of A = Q * (eigenvectors of T)
!         The NAG name equivalent of zunmtr is f08fuf
          Call zunmtr('Left',uplo,'No transpose',n,m,a,lda,tau,c,ldc,work,     &
            lwork,info)

!         Print eigenvectors
          Write (nout,*)
          Flush (nout)

!         Normalize the eigenvectors so that the element of largest absolute
!         value is real.
          Do i = 1, m
            rwork(1:n) = abs(c(1:n,i))
            k = maxloc(rwork(1:n),1)
            Call zscal(n,conjg(c(k,i))/cmplx(abs(c(k,i)),kind=nag_wp),c(1,i),1 &
              )
          End Do

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          Call x04dbf('General',' ',n,m,c,ldc,'Bracketed','F7.4',              &
            'Eigenvectors','Integer',rlabs,'Integer',clabs,80,0,ifail)

        End If
      End If

99999 Format (8X,4(F7.4,11X,:))
    End Program f08fufe