Program f08awfe

!     F08AWF Example Program Text

!     Mark 27.1 Release. NAG Copyright 2020.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x04dbf, zgelqf, zunglq
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, lda, lwork, m, n
      Character (30)                   :: title
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), tau(:), work(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout,*) 'F08AWF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n
      lda = m
      lwork = 64*m
      Allocate (a(lda,n),tau(n),work(lwork))

!     Read A from data file

      Read (nin,*)(a(i,1:n),i=1,m)

!     Compute the LQ factorization of A
!     The NAG name equivalent of zgelqf is f08avf
      Call zgelqf(m,n,a,lda,tau,work,lwork,info)

!     Form the leading M rows of Q explicitly
!     The NAG name equivalent of zunglq is f08awf
      Call zunglq(m,n,m,a,lda,tau,work,lwork,info)

!     Print the leading M rows of Q only

      Write (nout,*)
      Write (title,99999) m
      Flush (nout)

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04dbf('General',' ',m,n,a,lda,'Bracketed','F7.4',title,'Integer',  &
        rlabs,'Integer',clabs,80,0,ifail)

99999 Format ('The leading ',I2,' rows of Q')
    End Program f08awfe