Program f07ae_t1w_fe

!     F07AE_T1W_F Example Program Text
!     Mark 27 Release. NAG Copyright 2019.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07ad_t1w_f, f07ae_t1w_f,                       &
                               nagad_t1w_inc_derivative, nagad_t1w_w_rtype,    &
                               x10aa_t1w_f, x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, lwork, n, nrhs
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: a(:,:), a_in(:,:), b(:,:),      &
                                          b_in(:,:)
      Real (Kind=nag_wp), Allocatable  :: ar(:,:), br(:,:), dxdb(:,:)
      Integer, Allocatable             :: ipiv(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07AE_T1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, nrhs

      lwork = 64*n
      Allocate (a(n,n),a_in(n,n),ipiv(n))
      Allocate (b(n,nrhs),b_in(n,nrhs))
      Allocate (ar(n,n),br(n,nrhs),dxdb(n,n))

!     Read A from data file
      Read (nin,*)(ar(i,1:n),i=1,n)
      a_in = ar

!     Read B from data file
      Read (nin,*)(br(i,1:nrhs),i=1,n)
      b_in = br

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      a = a_in

!     Factorize A
      ifail = 0
      Call f07ad_t1w_f(ad_handle,n,n,a,n,ipiv,ifail)

      Write (nout,*)
      Flush (nout)

      Do i = 1, n

        Call nagad_t1w_inc_derivative(b_in(i,1),1.0_nag_wp)
        b = b_in

!       Solve system
        Call f07ae_t1w_f(ad_handle,'N',n,nrhs,a,n,ipiv,b,n,ifail)

        dxdb(1:n,i) = b(1:n,1)%tangent
        b_in(i,1)%tangent = 0.0_nag_wp
      End Do

!     Print solution
      br(1:n,1:nrhs) = b(1:n,1:nrhs)%value

!     ifail: behaviour on error exit
!            =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04caf('General',' ',n,nrhs,br,n,'Solution',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of solution X w.r.t. RHS B (A inverse)'
      Write (nout,*)
      Call x04caf('General',' ',n,n,dxdb,n,'       dx(i,1)/db(j,1)',ifail)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program f07ae_t1w_fe