Program c06fafe

!     C06FAF Example Program Text

!     Mark 27.1 Release. NAG Copyright 2020.

!     .. Use Statements ..
      Use nag_library, Only: c06faf, c06fbf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: ieof, ifail, j, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:), b(:), work(:), x(:), xx(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: mod
!     .. Executable Statements ..
      Write (nout,*) 'C06FAF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
loop: Do
        Read (nin,*,Iostat=ieof) n
        If (ieof<0) Then
          Exit loop
        End If
        Allocate (a(0:n-1),b(0:n-1),x(0:n-1),xx(0:n-1),work(n))
        Read (nin,*) x(0:n-1)
        xx(0:n-1) = x(0:n-1)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call c06faf(x,n,work,ifail)

        Write (nout,*)
        Write (nout,*) 'Components of discrete Fourier transform'
        Write (nout,*)
        Write (nout,*) '          Real      Imag'
        Write (nout,*)

!       Convert x to separated real and imaginary parts for printing.
        a(0:n/2) = x(0:n/2)
        a(n-1:n/2+1:-1) = x(1:n/2)
        b(0) = 0.0_nag_wp
        b(1:(n-1)/2) = x(n-1:n-(n-1)/2:-1)
        b(n-(n-1)/2:n-1) = -b((n-1)/2:1:-1)
        If (mod(n,2)==0) Then
          b(n/2) = 0.0_nag_wp
        End If

        Write (nout,99999)(j,a(j),b(j),j=0,n-1)

        x(n/2+1:n-1) = -x(n/2+1:n-1)
        Call c06fbf(x,n,work,ifail)

        Write (nout,*)
        Write (nout,*) 'Original sequence as restored by inverse transform'
        Write (nout,*)
        Write (nout,*) '        Original  Restored'
        Write (nout,*)
        Write (nout,99999)(j,xx(j),x(j),j=0,n-1)
        Deallocate (a,b,x,xx,work)
      End Do loop

99999 Format (1X,I5,2F10.5)
    End Program c06fafe