Program f07aufe

!     F07AUF Example Program Text

!     Mark 26.2 Release. NAG Copyright 2017.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, zgecon, zgetrf, zlange => f06uaf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: norm = '1'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: i, info, lda, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
      Integer, Allocatable             :: ipiv(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07AUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),work(2*n),rwork(2*n),ipiv(n))

!     Read A from data file

      Read (nin,*)(a(i,1:n),i=1,n)

!     Compute norm of A
!     f06uaf is the NAG name equivalent of the LAPACK auxiliary zlange
      anorm = zlange(norm,n,n,a,lda,rwork)

!     Factorize A
!     The NAG name equivalent of zgetrf is f07arf
      Call zgetrf(n,n,a,lda,ipiv,info)

      Write (nout,*)
      If (info==0) Then

!       Estimate condition number

!       The NAG name equivalent of zgecon is f07auf
        Call zgecon(norm,n,a,lda,anorm,rcond,work,rwork,info)

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number =',                 &
            1.0_nag_wp/rcond
        Else
          Write (nout,*) 'A is singular to working precision'
        End If
      Else
        Write (nout,*) 'The factor U is singular'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07aufe