Program f07fe_a1w_fe

!     F07FE_A1W_F Example Program Text
!     Mark 26.2 Release. NAG Copyright 2017.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07fd_a1w_f, f07fe_a1w_f,                       &
                               nagad_a1w_get_derivative,                       &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               nagad_a1w_ir_create, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, lda, ldb, n, nrhs
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Type (nagad_a1w_w_rtype), Allocatable :: a(:,:), ax(:,:), b(:,:), x(:,:)
      Real (Kind=nag_wp), Allocatable  :: ar(:,:), dxdb(:,:), xr(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FE_A1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, nrhs
      lda = n
      ldb = n
      Allocate (a(lda,n),b(ldb,nrhs),ax(lda,n),x(ldb,nrhs))
      Allocate (ar(lda,n),xr(ldb,nrhs),dxdb(n,n))

!     Read A and B from data file
      ar = 0.0_nag_wp
      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(ar(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(ar(i,1:i),i=1,n)
      End If
      a = ar
      Read (nin,*)(xr(i,1:nrhs),i=1,n)
      b = xr

!     Create AD tape
      Call nagad_a1w_ir_create

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Call nagad_a1w_ir_register_variable(a)
      Call nagad_a1w_ir_register_variable(b)
      ax = a
      x = b
!     Factorize A
      ifail = 0
      Call f07fd_a1w_f(ad_handle,uplo,n,ax,lda,ifail)

      Write (nout,*)
      Flush (nout)

!     Compute solution
!     The NAG name equivalent of dpotrs_dco_a1w is f07fef_dco_a1w
      Call f07fe_a1w_f(ad_handle,uplo,n,nrhs,ax,lda,x,ldb,ifail)

!     Print solution
      xr(1:n,1:nrhs) = x(1:n,1:nrhs)%value

!     ifail: behaviour on error exit
!            =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04caf('General',' ',n,nrhs,xr,ldb,'Solution(s)',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order adjoints'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of solution x(:,1) w.r.t. b(:,1)'
      Write (nout,*) ' (i.e. The inverse of A) :'
!     Setup evaluation of derivatives via adjoints
      Do i = 1, n
        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(x(i,1),1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        dxdb(i,1:n) = nagad_a1w_get_derivative(b(1:n,1))
      End Do
      Call x04caf('General',' ',n,n,dxdb,n,'',ifail)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program f07fe_a1w_fe