Program f11mhfe

!     F11MHF Example Program Text

!     Mark 25 Release. NAG Copyright 2014.

!     .. Use Statements ..
      Use nag_library, Only: f11mdf, f11mef, f11mff, f11mhf, nag_wp, x04caf,   &
                             x04cbf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: one = 1.E0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: flop, thresh
      Integer                          :: i, ifail, j, ldb, ldx, n, nnz, nnzl, &
                                          nnzu, nrhs, nzlmx, nzlumx, nzumx
      Character (1)                    :: spec, trans
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:), b(:,:), berr(:), ferr(:),      &
                                          lval(:), uval(:), x(:,:)
      Integer, Allocatable             :: icolzp(:), il(:), iprm(:),           &
                                          irowix(:), iu(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout,*) 'F11MHF Example Program Results'
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)

!     Read order of matrix and number of right hand sides

      Read (nin,*) n, nrhs
      ldb = n
      ldx = n

      Allocate (b(ldb,nrhs),berr(nrhs),ferr(nrhs),x(ldx,nrhs),icolzp(n+1), &
        iprm(7*n))

!     Read the matrix A

      Read (nin,*) icolzp(1:n+1)
      nnz = icolzp(n+1) - 1

      Allocate (a(nnz),lval(8*nnz),uval(8*nnz),il(7*n+8*nnz+4),irowix(nnz), &
        iu(2*n+8*nnz+1))

      Do i = 1, nnz
        Read (nin,*) a(i), irowix(i)
      End Do

!     Read the right hand sides

      Do j = 1, nrhs
        Read (nin,*) x(1:n,j)
        b(1:n,j) = x(1:n,j)
      End Do

!     Calculate COLAMD permutation

      spec = 'M'

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call f11mdf(spec,n,icolzp,irowix,iprm,ifail)

!     Factorise

      thresh = one
      ifail = 0
      nzlmx = 8*nnz
      nzlumx = 8*nnz
      nzumx = 8*nnz

      Call f11mef(n,irowix,a,iprm,thresh,nzlmx,nzlumx,nzumx,il,lval,iu,uval, &
        nnzl,nnzu,flop,ifail)

!     Compute solution in array X

      trans = 'N'

      ifail = 0
      Call f11mff(trans,n,iprm,il,lval,iu,uval,nrhs,x,ldx,ifail)

!     Improve solution, and compute backward errors and estimated
!     bounds on the forward errors

      Call f11mhf(trans,n,icolzp,irowix,a,iprm,il,lval,iu,uval,nrhs,b,ldb,x, &
        ldx,ferr,berr,ifail)

!     Print solution

      Write (nout,*)
      Flush (nout)

      Call x04caf('G',' ',n,nrhs,x,ldx,'Solutions',ifail)
      Call x04cbf('G','X',nrhs,1,ferr,nrhs,'1PE8.1','Estimated Forward Error', &
        'N',rlabs,'N',clabs,80,0,ifail)
      Call x04cbf('G','X',nrhs,1,berr,nrhs,'1PE8.1','Backward Error','N', &
        rlabs,'N',clabs,80,0,ifail)

    End Program f11mhfe