Program f07tgfe

!     F07TGF Example Program Text

!     Mark 25 Release. NAG Copyright 2014.

!     .. Use Statements ..
      Use nag_library, Only: dtrcon, nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: diag = 'N', norm = '1'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: rcond
      Integer                          :: i, info, lda, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), work(:)
      Integer, Allocatable             :: iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07TGF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),work(3*n),iwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Estimate condition number
!     The NAG name equivalent of dtrcon is f07tgf
      Call dtrcon(norm,uplo,diag,n,a,lda,rcond,work,iwork,info)

      Write (nout,*)
      If (rcond>=x02ajf()) Then
        Write (nout,99999) 'Estimate of condition number =', &
          1.0E0_nag_wp/rcond
      Else
        Write (nout,*) 'A is singular to working precision'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07tgfe