Program f07brfe

!     F07BRF Example Program Text

!     Mark 25 Release. NAG Copyright 2014.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x04dff, zgbtrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, j, k, kl, ku, ldab,  &
                                          m, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ab(:,:)
      Integer, Allocatable             :: ipiv(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F07BRF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n, kl, ku
      ldab = 2*kl + ku + 1
      Allocate (ab(ldab,n),ipiv(n))

!     Read A from data file

      k = kl + ku + 1
      Read (nin,*)((ab(k+i-j,j),j=max(i-kl,1),min(i+ku,n)),i=1,m)

!     Factorize A
!     The NAG name equivalent of zgbtrf is f07brf
      Call zgbtrf(m,n,kl,ku,ab,ldab,ipiv,info)

!     Print details of factorization

      Write (nout,*)
      Flush (nout)

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04dff(m,n,kl,kl+ku,ab,ldab,'Bracketed','F7.4', &
        'Details of factorization','Integer',rlabs,'Integer',clabs,80,0,ifail)

!     Print pivot indices

      Write (nout,*)
      Write (nout,*) 'IPIV'
      Write (nout,99999) ipiv(1:min(m,n))

      If (info/=0) Write (nout,*) 'The factor U is singular'

99999 Format ((1X,I12,3I18))
    End Program f07brfe