!   D02PZF Example Program Text
!   Mark 25 Release. NAG Copyright 2014.

    Module d02pzfe_mod

!     D02PZF Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                               :: f
!     .. Parameters ..
      Integer, Parameter, Public           :: neq = 4, nin = 5, nout = 6
      Integer, Parameter, Public           :: lenwrk = 32*neq
    Contains
      Subroutine f(t,y,yp)

!       .. Scalar Arguments ..
        Real (Kind=nag_wp), Intent (In)      :: t
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (In)      :: y(*)
        Real (Kind=nag_wp), Intent (Out)     :: yp(*)
!       .. Local Scalars ..
        Real (Kind=nag_wp)                   :: r
!       .. Intrinsic Procedures ..
        Intrinsic                            :: sqrt
!       .. Executable Statements ..
        r = sqrt(y(1)**2+y(2)**2)
        yp(1) = y(3)
        yp(2) = y(4)
        yp(3) = -y(1)/r**3
        yp(4) = -y(2)/r**3
        Return
      End Subroutine f
    End Module d02pzfe_mod

    Program d02pzfe

!     D02PZF Example Main Program

!     .. Use Statements ..
      Use nag_library, Only: d02pcf, d02pvf, d02pyf, d02pzf, nag_wp
      Use d02pzfe_mod, Only: f, lenwrk, neq, nin, nout
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Real (Kind=nag_wp)                   :: errmax, hnext, hstart, tend,     &
                                              terrmx, tgot, tol, tstart,       &
                                              twant, waste
      Integer                              :: ifail, method, stpcst, stpsok,   &
                                              totf
      Logical                              :: errass
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable      :: rmserr(:), thres(:), work(:),    &
                                              ygot(:), ymax(:), ypgot(:),      &
                                              ystart(:)
!     .. Executable Statements ..
      Write (nout,*) 'D02PZF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
!     neq: number of differential equations
      Read (nin,*) method
      Allocate (rmserr(neq),thres(neq),work(lenwrk),ygot(neq),ymax(neq), &
        ypgot(neq),ystart(neq))

!     Set initial conditions and input for D02PVF

      Read (nin,*) tstart, tend
      Read (nin,*) ystart(1:neq)
      Read (nin,*) hstart, tol
      Read (nin,*) thres(1:neq)
      Read (nin,*) errass

!     ifail: behaviour on error exit   
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call d02pvf(neq,tstart,ystart,tend,tol,thres,method,'Usual Task',errass, &
        hstart,work,lenwrk,ifail)

      Write (nout,99999) tol
      Write (nout,99998)
      Write (nout,99997) tstart, ystart(1:neq)

      twant = tend

integ: Do
        ifail = -1
        Call d02pcf(f,twant,tgot,ygot,ypgot,ymax,work,ifail)

        If (ifail<2 .Or. ifail>4) Then
          Exit integ
        End If

      End Do integ

      If (ifail==0) Then

!       Print solution.
        Write (nout,99997) tgot, ygot(1:neq)

!       Compute and print error estimates.
        ifail = 0
        Call d02pzf(rmserr,errmax,terrmx,work,ifail)

        Write (nout,99996) rmserr(1:neq)
        Write (nout,99995) errmax, terrmx

        ifail = 0
        Call d02pyf(totf,stpcst,waste,stpsok,hnext,ifail)

        Write (nout,99994) totf
      End If

99999 Format (/' Calculation with TOL = ',E8.1)
99998 Format (/'    t         y1         y2         y3         y4'/)
99997 Format (1X,F6.3,4(3X,F8.4))
99996 Format (/' Componentwise error assessment'/9X,4(2X,E9.2))
99995 Format (/' Worst global error observed was ',E9.2, &
        ' - it occurred at T = ',F6.3)
99994 Format (/' Cost of the integration in evaluations of F is',I6)
    End Program d02pzfe