Program f07hrfe

!     F07HRF Example Program Text

!     Mark 26.2 Release. NAG Copyright 2017.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x04dff, zpbtrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, j, kd, ldab, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ab(:,:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F07HRF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, kd
      ldab = kd + 1
      Allocate (ab(ldab,n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Do i = 1, n
          Read (nin,*)(ab(kd+1+i-j,j),j=i,min(n,i+kd))
        End Do
      Else If (uplo=='L') Then
        Do i = 1, n
          Read (nin,*)(ab(1+i-j,j),j=max(1,i-kd),i)
        End Do
      End If

!     Factorize A
!     The NAG name equivalent of zpbtrf is f07hrf
      Call zpbtrf(uplo,n,kd,ab,ldab,info)

      Write (nout,*)
      Flush (nout)
      If (info==0) Then

!       Print factor

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        If (uplo=='U') Then

          Call x04dff(n,n,0,kd,ab,ldab,'Bracketed','F7.4','Factor','Integer',  &
            rlabs,'Integer',clabs,80,0,ifail)

        Else If (uplo=='L') Then

          Call x04dff(n,n,kd,0,ab,ldab,'Bracketed','F7.4','Factor','Integer',  &
            rlabs,'Integer',clabs,80,0,ifail)

        End If

      Else
        Write (nout,*) 'A is not positive definite'
      End If

    End Program f07hrfe