Program f07atfe

!     F07ATF Example Program Text

!     Mark 26.2 Release. NAG Copyright 2017.

!     .. Use Statements ..
      Use nag_library, Only: f06kcf, nag_wp, x02ajf, x02amf, x02bhf, x04dbf,   &
                             zdscal, zgeequ
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: one = 1.0_nag_wp
      Real (Kind=nag_wp), Parameter    :: thresh = 0.1_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: amax, big, colcnd, rowcnd, small
      Integer                          :: i, ifail, info, j, lda, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:)
      Real (Kind=nag_wp), Allocatable  :: c(:), r(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: real
!     .. Executable Statements ..
      Write (nout,*) 'F07ATF Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),c(n),r(n))

!     Read the N by N matrix A from data file

      Read (nin,*)(a(i,1:n),i=1,n)

!     Print the matrix A

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04dbf('General',' ',n,n,a,lda,'Bracketed','1P,E10.2','Matrix A',   &
        'Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)

!     Compute row and column scaling factors

!     The NAG name equivalent of zgeequ is f07atf
      Call zgeequ(n,n,a,lda,r,c,rowcnd,colcnd,amax,info)

      If (info>0) Then
        If (info<=n) Then
          Write (nout,99999) 'Row ', info, ' of A is exactly zero'
        Else
          Write (nout,99999) 'Column ', info - n, ' of A is exactly zero'
        End If
      Else

!       Print ROWCND, COLCND, AMAX and the scale factors

        Write (nout,99998) 'ROWCND =', rowcnd, ', COLCND =', colcnd,           &
          ', AMAX =', amax
        Write (nout,*)
        Write (nout,*) 'Row scale factors'
        Write (nout,99997) r(1:n)
        Write (nout,*)
        Write (nout,*) 'Column scale factors'
        Write (nout,99997) c(1:n)
        Write (nout,*)
        Flush (nout)

!       Compute values close to underflow and overflow

        small = x02amf()/(x02ajf()*real(x02bhf(),kind=nag_wp))
        big = one/small
        If ((rowcnd>=thresh) .And. (amax>=small) .And. (amax<=big)) Then
          If (colcnd<thresh) Then

!           Just column scale A
!           The NAG name equivalent of zdscal is f06jdf
            Do j = 1, n
              Call zdscal(n,c(j),a(1,j),1)
            End Do

          End If
        Else If (colcnd>=thresh) Then

!         Just row scale A
          Do j = 1, n
            Call f06kcf(n,r,1,a(1,j),1)
          End Do

        Else

!         Row and column scale A
          Do j = 1, n
            Call zdscal(n,c(j),a(1,j),1)
            Call f06kcf(n,r,1,a(1,j),1)
          End Do

        End If

!       Print the scaled matrix
        ifail = 0
        Call x04dbf('General',' ',n,n,a,lda,'Bracketed',' ','Scaled matrix',   &
          'Integer',rlabs,'Integer',clabs,80,0,ifail)

      End If

99999 Format (1X,A,I4,A)
99998 Format (1X,3(A,1P,E8.1))
99997 Format ((1X,1P,7E11.2))
    End Program f07atfe