Program f07jnfe

!     F07JNF Example Program Text

!     Mark 26.1 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, zptsv
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: info, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: b(:), e(:)
      Real (Kind=nag_wp), Allocatable  :: d(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07JNF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (b(n),e(n-1),d(n))

!     Read the lower bidiagonal part of the tridiagonal matrix A and
!     the right hand side b from data file

      Read (nin,*) d(1:n)
      Read (nin,*) e(1:n-1)
      Read (nin,*) b(1:n)

!     Solve the equations Ax = b for x
!     The NAG name equivalent of zptsv is f07jnf
      Call zptsv(n,1,d,e,b,n,info)

      If (info==0) Then

!       Print solution

        Write (nout,*) 'Solution'
        Write (nout,99999) b(1:n)

!       Print details of factorization

        Write (nout,*)
        Write (nout,*) 'Diagonal elements of the diagonal matrix D'
        Write (nout,99998) d(1:n)
        Write (nout,*)
        Write (nout,*) 'Subdiagonal elements of the Cholesky factor L'
        Write (nout,99999) e(1:n-1)

      Else
        Write (nout,99997) 'The leading minor of order ', info,                &
          ' is not positive definite'
      End If

99999 Format (4(' (',F8.4,',',F8.4,')',:))
99998 Format ((2X,F7.4,3(11X,F7.4)))
99997 Format (1X,A,I3,A)
    End Program f07jnfe