Program f08yffe

!     F08YFF Example Program Text

!     Mark 26.1 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: dtgexc, nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Logical, Parameter               :: wantq = .False., wantz = .False.
!     .. Local Scalars ..
      Integer                          :: i, ifail, ifst, ilst, info, lda,     &
                                          ldb, ldq, ldz, lwork, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), b(:,:), q(:,:), work(:),     &
                                          z(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F08YFF Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldq = 1
      ldz = 1
      lda = n
      ldb = n
      lwork = 4*n + 16
      Allocate (a(lda,n),b(ldb,n),q(ldq,1),work(lwork),z(ldz,1))

!     Read A and B from data file

      Read (nin,*)(a(i,1:n),i=1,n)
      Read (nin,*)(b(i,1:n),i=1,n)

!     Read the row indices

      Read (nin,*) ifst, ilst

!     Reorder A and B

!     The NAG name equivalent of dtgexc is f08yff
      Call dtgexc(wantq,wantz,n,a,lda,b,ldb,q,ldq,z,ldz,ifst,ilst,work,lwork,  &
        info)

      If (info/=0) Then
        Write (nout,99999) info, ilst
        Write (nout,*)
        Flush (nout)
      End If

!     The resulting reordered Schur matrices can differ by +- signs by
!     multiplying rows and columns of Q and Z by -1. We will normalize here by
!     making the diagonals and last column of B positive.
      Call normalize(a,b)

!     Print reordered generalized Schur form

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04caf('General',' ',n,n,a,lda,'Reordered Schur matrix A',ifail)

      Write (nout,*)
      Flush (nout)

      ifail = 0
      Call x04caf('General',' ',n,n,b,ldb,'Reordered Schur matrix B',ifail)

99999 Format (' Reordering could not be completed. INFO = ',I3,' ILST = ',I5)

    Contains
      Subroutine normalize(a,b)

!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (Inout) :: a(lda,n), b(ldb,n)
!       .. Local Scalars ..
        Integer                        :: i, j
!       .. Intrinsic Procedures ..
        Intrinsic                      :: max
!       .. Executable Statements ..

!       Last column of B positive
        Do i = 1, n
          j = max(1,i-1)
          If (b(i,n)<0.0_nag_wp) Then
            a(i,j:n) = -a(i,j:n)
            b(i,i:n) = -b(i,i:n)
          End If
        End Do

!       Diagonals of B positive
        Do i = 1, n - 1
          If (b(i,i)<0.0_nag_wp) Then
            a(1:i+1,i) = -a(1:i+1,i)
            b(1:i,i) = -b(1:i,i)
          End If
        End Do
      End Subroutine normalize
    End Program f08yffe