Program f07nufe

!     F07NUF Example Program Text

!     Mark 26.1 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, zlansy => f06uff, zsycon, zsytrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: i, info, lda, lwork, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
      Integer, Allocatable             :: ipiv(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07NUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      lwork = 64*n
      Allocate (a(lda,n),work(lwork),rwork(n),ipiv(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Compute norm of A
!     f06uff is the NAG name equivalent of the LAPACK auxiliary zlansy
      anorm = zlansy('1-norm',uplo,n,a,lda,rwork)

!     Factorize A
!     The NAG name equivalent of zsytrf is f07nrf
      Call zsytrf(uplo,n,a,lda,ipiv,work,lwork,info)

      Write (nout,*)
      If (info==0) Then

!       Estimate condition number
!       The NAG name equivalent of zsycon is f07nuf
        Call zsycon(uplo,n,a,lda,ipiv,anorm,rcond,work,info)

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number =',                 &
            1.0_nag_wp/rcond
        Else
          Write (nout,*) 'A is singular to working precision'
        End If
      Else
        Write (nout,*) 'The factor D is singular'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07nufe